      SUBROUTINE CSSCAL( N, SA, CX, INCX )
*
*     scales a complex vector by a real constant.
*     jack dongarra, linpack, 3/11/78.
*
*     .. Scalar Arguments ..
      INTEGER            INCX, N
      REAL               SA
*     ..
*     .. Array Arguments ..
      COMPLEX            CX( 1 )
*     ..
*     .. Local Scalars ..
      INTEGER            I, IX, NINCX
*     ..
*     .. Intrinsic Functions ..
      INTRINSIC          AIMAG, CMPLX, REAL
*     ..
*     .. Executable Statements ..
*
      IF( N.LE.0 )
     $   RETURN
      IF( INCX.EQ.1 )
     $   GO TO 20
*
*        code for increment not equal to 1
*
      IX = 1
      IF( INCX.LT.0 )
     $   IX = 1 - ( N-1 )*INCX
      NINCX = IX + ( N-1 )*INCX
      DO 10 I = IX, NINCX, INCX
         CX( I ) = CMPLX( SA*REAL( CX( I ) ), SA*AIMAG( CX( I ) ) )
   10 CONTINUE
      RETURN
*
*        code for increment equal to 1
*
   20 DO 30 I = 1, N
         CX( I ) = CMPLX( SA*REAL( CX( I ) ), SA*AIMAG( CX( I ) ) )
   30 CONTINUE
      RETURN
      END
